9 replies to this topic

[Acleacius]

Any chance of fixing Shoal or how I could do it myself, with NP++? The idea that all resistances to magic/death magic are just throw out the window, qualify this as one of the the worst quests ever written. The whole fact of making a protagonist is to use them, not to stick them in the back. Afaik the whole game was written as speaking to the protagonist. So this is 4th wall, you can't not die. You can't not, use afterthought knowledge.

The quest would work very well, if she TRIES to kill with a kiss. Then party attacks till dialog break, then decision.

Just to be clear, I would like to remove the auto death, make it an *attempt* just like all the assassins. Is there a mod or could someone please mention which script and what to edit?


Thanks for any help.

[Quester]

Completely agree, I've always thought that encounter was an example of very poor game design, since you have no in game or in character chance of avoiding death, unless you know about it beforehand and attack her on sight. It ends up simply being an annoying experience. It's very strange that no mod has changed how this encounter works (at least to my knowledge).

[Dakk]

Acleacius, on 06 January 2012 - 01:02 PM, said:

The idea that all resistances to magic/death magic are just throw out the window, qualify this as one of the the worst quests ever written.[...] The quest would work very well, if she TRIES to kill with a kiss. Then party attacks till dialog break, then decision.
Just to be clear, I would like to remove the auto death, make it an *attempt* just like all the assassins. Is there a mod or could someone please mention which script and what to edit?

I couldn't agree more, and that should be changed.

Quester, on 06 January 2012 - 01:45 PM, said:

Completely agree, I've always thought that encounter was an example of very poor game design, since you have no in game or in character chance of avoiding death, unless you know about it beforehand and attack her on sight. It ends up simply being an annoying experience. It's very strange that no mod has changed how this encounter works (at least to my knowledge).

It sure is, and it actually baffles me too that it's never been modded (afaik)...

[aVENGER_(RR)]

For what it's worth, when I get around to adding the "PnP Elementals" component to aTweaks, I do intend to handle the Shoal encounter a bit differently.

A Nereid's kiss should definitively allow a saving throw (vs. breath at a -2 penalty) and I will probably make some adjustments to her dialogue to reflect this.

[Salk]

I will be welcoming those changes, aVENGER_(RR).

One thing that could be done is to simply script it so that she kisses the protagonist only if there are no other (male?) party members.

[Dakk]

aVENGER_(RR), on 06 January 2012 - 10:58 PM, said:

For what it's worth, when I get around to adding the "PnP Elementals" component to aTweaks, I do intend to handle the Shoal encounter a bit differently.

A Nereid's kiss should definitively allow a saving throw (vs. breath at a -2 penalty) and I will probably make some adjustments to her dialogue to reflect this.

Very glad to hear that! And knowing your previous work with, for example, Fey creatures, I'm sure it'll turn out great :-)

[Acleacius]

Glad there is interest in fixing this quest. This one minor change would transform this quest/encounter from terrible to very good, in all it's a pretty unique quest plot.

At least until we can get a community fix, does anyone know which script would need to be edited or is it not as simple as removing the auto death, yet allowing it to proceed as a normal attack? On the surface it seems like letting it just be a normal attack (as a quick fix) could work.


Thanks for the replies.


Edit: Is there a forum here where I can ask Non-Mod, game related questions? There could be a mod for this (which would be great)...trying to find out if there is a romance track for Viconia in BG, everything I see, seems to relate to BG2.

Edited by Acleacius, 07 January 2012 - 12:29 PM.

[cmorgan]

When folks update this, someone let me know - if I recall correctly, BG1NPC has material that may need adjusting (both interjections and follow up).

[Dakk]

Offhand, do you remember if the interjections in any way stop the (protagonist, at least) auto-death?

[aVENGER_(RR)]

cmorgan, on 08 January 2012 - 08:50 AM, said:

When folks update this, someone let me know - if I recall correctly, BG1NPC has material that may need adjusting (both interjections and follow up).

Here you go:

// Shoal's kiss should not be forced upon the party

<<<<<<<<atweaks/inlined/baf/elementals/shoal.baf
IF
    NumTimesTalkedToGT(0)
    Global("rr#intd","LOCALS",0)
    !Dead("Droth")
    HPPercentLT(Myself,51)
    See([PC])    
THEN
	RESPONSE #100
        SetGlobal("rr#intd","LOCALS",1)
        SetGlobal("ShoalHit","GLOBAL",1)
        FaceObject([PC])
        StartDialogueNoSet([PC])
END
>>>>>>>>

ACTION_FOR_EACH ~file~ IN                                                          // for each of the following files
               ~shoal~                                                             // Shoal's script (BGT)
              ~_shoal~                                                             // Shoal's script (Tutu)
BEGIN                                                                              // execute the following
ACTION_IF FILE_EXISTS_IN_GAME ~%file%.bcs~ BEGIN                                   // if the designated file with a BCS extension exists
COPY_EXISTING ~%file%.bcs~ ~override~
PATCH_IF (%SOURCE_SIZE% > 0x01) THEN BEGIN                                         // file size sanity check (filters out 0 byte files i.e. ALLOW_MISSING)
DECOMPILE_BCS_TO_BAF
  REPLACE_TEXTUALLY EXACT_MATCH ~HitBy([PC],CRUSHING)~ ~AttackedBy([PC],DEFAULT) NumTimesTalkedTo(0)~
  REPLACE_TEXTUALLY EXACT_MATCH ~Dialogue([PC])~ ~FaceObject([PC]) StartDialogueNoSet([PC])~
  REPLACE_TEXTUALLY EXACT_MATCH ~Dialog([PC])~ ~FaceObject([PC]) StartDialogueNoSet([PC])~
COMPILE_BAF_TO_BCS
END                                                                                // ends file size check
BUT_ONLY_IF_IT_CHANGES
EXTEND_BOTTOM ~%file%.bcs~  ~atweaks/inlined/baf/elementals/shoal.baf~             // extend Shoal's script
END                                                                                // ends ACTION_IF FILE_EXISTS_IN_GAME block
END                                                                                // ends ACTION_FOR_EACH block

<<<<<<<<atweaks/inlined/dlg/elementals/shoal.d
ALTER_TRANS ~%TUTU_VAR%SHOAL~ BEGIN 3 END BEGIN 0 END BEGIN
  "REPLY" ~#70151~ // Alright...
END

EXTEND_BOTTOM ~%TUTU_VAR%SHOAL~ 3 
  IF ~~ THEN REPLY #33428 GOTO rr#shl01 // I said no and I mean it.
END

APPEND ~%TUTU_VAR%SHOAL~
  IF ~~ THEN BEGIN rr#shl01
    SAY @2114 // So be it, then! I do not wish to fight you <RACE>, but I have little choice in the matter.
  IF ~~ THEN DO ~SetGlobal("ShoalHit","GLOBAL",1) Enemy()~ EXIT
  END
END
>>>>>>>>

ACTION_IF GAME_IS ~bgt tutu tutu_totsc~ THEN BEGIN
  COMPILE EVALUATE_BUFFER ~atweaks/inlined/dlg/elementals/shoal.d~
END

Hopefully, these changes won't break any interjections. Refusing the kiss will simply turn Shoal hostile and make her attack the party until her hit points drop below 50%. The quest then proceeds exactly as if the party had attacked Shoal before talking to her, which can be done in the unmodded game.

Edited by aVENGER_(RR), 17 February 2012 - 08:11 AM.