45 replies to this topic

[cmorgan]

Thanks! Looks like I will have to go back over this one (for the 300th time).

[erebusant]

cmorgan, on May 10 2009, 04:10 PM, said:

Thanks! Looks like I will have to go back over this one (for the 300th time).

Looking at X#Andart.bcs the pertinent code begins at line 8200 or so. Moving the BG1NPC code to the beginning of the bcs file prior to the SCS added code allows the JaheiraHealsB global to be set to 6 and Andarthe to initiate the dialog with the party. I still ran into the issue with blowing Andarthe up without giving him the opportunity to surrender. I would suggest giving him a MINHP1 item (works fine in my game) so he can dialog and surrender, and if the party allows the surrender, provide the same XP by dialog and let him escape, and if the party chooses to kill him anyway, destroy the MINHP1 item by dialog and ApplySpell(Myself,RESTORE_FULL_HEALTH) and summon a few more beasties and shadow druids by script to assist. By the way, BGT has _WOLFDR.cre as the .cre's that are summoned which are non-existant resources in BGT. They would need to be WOLFDR.cre to work.

Edited by erebusant, 10 May 2009 - 05:08 PM.

[cmorgan]

Great pointers! Tejumin got me straightened out on the missallocated .cre stuff - i'll check with DavidW to find out how to deal with SCS/SCSII.

[erebusant]

marceror, on May 28 2009, 10:19 PM, said:

Hi all. I could use some help on this one also.

My situation is currently

Archdruid upstairs: dead
Guy in wyvern area: Alive
Archdruid outside treehouse: Won't dialogue. He and a druid buddy both "have nothing to say" to me.


If I fight the archdruid his friend doesn't go hostile. I can kill them both, one after the other, but Maretha (sp?) doesn't spawn inside the treehouse.

Would appreciate an appropriate code to get me back on track!

By the way, the NPC mod is just fantastic! It several points it's nearly brought me to tears. I think I'm falling for Dyaneir (don't let my wife know). Her "yes" during a certain intimate moment, almost made me fall off my chair, hehe. Damn good writing in this mod.

Looking at X#Andart.bcs the pertinent code begins at line 8200 or so. Moving the BG1NPC code to the beginning of the bcs file prior to the SCS added code allows the JaheiraHealsB global to be set to 6 and Andarthe to initiate the dialog with the party. You need to go back to your auto-save from travelling back to the druid area from the wyvern area for this to be effective. The code from the bcs file is as follows in a BGT game:

IF
	Global("X#JaheiraHealsB","GLOBAL",5)
	Detect([PC])
	InMyArea("jaheira")
	!StateCheck("jaheira",CD_STATE_NOTVALID)
	InMyArea(Player1)
	!StateCheck(Player1,CD_STATE_NOTVALID)
THEN
	RESPONSE #100
		SetGlobal("X#JaheiraHealsB","GLOBAL",6)
END

IF
	Global("X#JaheiraHealsB","GLOBAL",6)
	InMyArea("jaheira")
	!StateCheck("jaheira",CD_STATE_NOTVALID)
	InMyArea(Player1)
	!StateCheck(Player1,CD_STATE_NOTVALID)
THEN
	RESPONSE #100
		StartDialogueNoSet([PC])
END

IF
	Global("X#JQBeadorDead","GLOBAL",2)
	Detect([PC])
	InMyArea("jaheira")
	!StateCheck("jaheira",CD_STATE_NOTVALID)
	InMyArea(Player1)
	!StateCheck(Player1,CD_STATE_NOTVALID)
THEN
	RESPONSE #100
		SetGlobal("X#JQBeadorDead","GLOBAL",3)
END

IF
	Global("X#JQBeadorDead","GLOBAL",3)
	InMyArea("jaheira")
	!StateCheck("jaheira",CD_STATE_NOTVALID)
	InMyArea(Player1)
	!StateCheck(Player1,CD_STATE_NOTVALID)
THEN
	RESPONSE #100
		StartDialogueNoSet(Player1)
END

IF
	Global("X#JaheiraQuestAAttack","GLOBAL",1)
THEN
	RESPONSE #100
		SetGlobal("X#JaheiraQuestAAttack","GLOBAL",2)
		ActionOverride("jadruid8a",Enemy())
		ActionOverride("takiyah",Enemy())
		JumpToPoint([874.2175])
		FaceObject(Player1)
		CreateCreature("WOLFDR",[-1.-1],0) // Dread Wolf
		CreateCreature("WOLFDR",[-1.-1],0) // Dread Wolf
		Enemy()
END

IF
	HasItem("X#ANSPER",Myself) // Flaming Spear +1
	HPPercentLT(Myself,50)
THEN
	RESPONSE #100
		DropItem("X#ANSPER",[-1.-1]) // Flaming Spear +1
END

IF
	Global("X#AndSurrender","GLOBAL",0)
	HPPercentLT(Myself,50)
THEN
	RESPONSE #100
		SetGlobal("X#AndSurrender","GLOBAL",1)
		ChangeEnemyAlly(Myself,NEUTRAL)
		StartDialogueNoSet([PC])
END

[cmorgan]

erebusant, on May 10 2009, 08:08 PM, said:

Looking at X#Andart.bcs the pertinent code begins at line 8200 or so. Moving the BG1NPC code to the beginning of the bcs file prior to the SCS added code allows the JaheiraHealsB global to be set to 6 and Andarthe to initiate the dialog with the party.

Flagging as a separate problem for SCS/DavidW, as we can't do anything to the .bcs that won't end up with SCS adding on top.

[cmorgan]

temujin_, on Mar 21 2009, 09:38 PM, said:

there's also another bug (unrelated to SCS) regarding the quest given by Izefia. he gives you the reward once you clear out the cave, but talking to him one more time resets his dialog and he delivers the same "Faldorn travels with you..." line that starts the quest.

Dammit. I so, so wanted to never add another line of dialog. I am searching all of the .tra files for a simple phrase I can cut and paste into this - basically, we need something that overrides the whole dialog at the end. A simple

APPEND ~%tutu_var%IZEFIA~

IF WEIGHT #-1 ~Global("X#ReportIzefia","GLOBAL",2)~ THEN BEGIN x#fqisover
  SAY ~ <<PLACEHOLDER>> ~
  IF ~~ THEN EXIT
END

END

Searching...

AHAH!

x#faint.tra, same file, @175 = ~Be strong! Go with the Nature's blessings.~

and for not done yet,

@157 = ~My time is my own. You will not place demands on it.~

and for player if Faldorn is unavailable and

@151 = ~No, not yet. We'll go look for him right now.~

And a better idea would be to send him away after the quest is over anyways. He does not have additional content.

So, no added .tra lines - an EscapeArea for him once the Faldorn quest is completed, and an intermediate state for the quest not being completed:
changes to x#faint.d

/* Faldorn Izefia ICT  to set Quest */

I_C_T ~%tutu_var%IZEFIA~ 1 X#FALDORNIZEFIA1
== ~%FALDORN_JOINED%~ IF ~InParty("faldorn") InMyArea("faldorn") !StateCheck("faldorn",CD_STATE_NOTVALID)~ THEN @56
== ~%tutu_var%IZEFIA~ IF ~InParty("faldorn") InMyArea("faldorn") !StateCheck("faldorn",CD_STATE_NOTVALID)~ THEN @57
DO ~SetGlobal("X#ReportIzefia","GLOBAL",1)~
END

/* Faldorn Izefia Quest Done  */

CHAIN IF WEIGHT #-1 ~%BGT_VAR% Global("X#ReportIzefia","GLOBAL",1) Dead("peter") InParty("faldorn") InMyArea("faldorn") !StateCheck("faldorn",CD_STATE_NOTVALID)~
THEN ~%tutu_var%IZEFIA~ X#IzeFaldo2
@58
== ~%FALDORN_JOINED%~ @59
== ~%tutu_var%IZEFIA~ @60
== ~%FALDORN_JOINED%~ @61
== ~%tutu_var%IZEFIA~ @62
DO ~SetGlobal("X#ReportIzefia","GLOBAL",2) AddXPObject("faldorn",100) GiveItemCreate("%tutu_var%POTN08","faldorn",1,0,0) GiveItemCreate("%tutu_var%POTN20","faldorn",1,0,0)~
EXIT

/* Faldorn Izefia Quest Done BUT Faldorn Not OK/In Party */

CHAIN IF WEIGHT #-1 ~%BGT_VAR% Global("X#ReportIzefia","GLOBAL",1) Dead("peter") OR(3) !InParty("faldorn") !InMyArea("faldorn") StateCheck("faldorn",CD_STATE_NOTVALID)~
THEN ~%tutu_var%IZEFIA~ X#IzeFaldoNotYet1
@58
END
++ @151 EXIT

/* Faldorn Izefia Quest Not Done or Faldorn Not OK/In Party */
CHAIN IF WEIGHT #-1 ~%BGT_VAR% Global("X#ReportIzefia","GLOBAL",1) !Dead("peter") OR(3) !InParty("faldorn") !InMyArea("faldorn") StateCheck("faldorn",CD_STATE_NOTVALID)~
THEN ~%tutu_var%IZEFIA~ X#IzeFaldoNotYet2
@58
END
++ @151 EXIT

/* Faldorn Izefia Quest Not Done but Faldorn OK/In Party */

CHAIN IF WEIGHT #-1 ~%BGT_VAR% Global("X#ReportIzefia","GLOBAL",1) !Dead("peter") InParty("faldorn") InMyArea("faldorn") !StateCheck("faldorn",CD_STATE_NOTVALID)~
THEN ~%tutu_var%IZEFIA~ X#IzeFaldoNotYet
@58
== ~%FALDORN_JOINED%~ @157
== ~%tutu_var%IZEFIA~ @175
EXIT

for docs:

<li> <a href="http://forums.gibberlings3.net/index.php?s=&showtopic=16588&view=findpost&p=152337"> Faldorn/Izefia Quest loophole repaired</a> </li>

[cmorgan]

erebusant, on May 10 2009, 08:08 PM, said:

Looking at X#Andart.bcs the pertinent code begins at line 8200 or so. Moving the BG1NPC code to the beginning of the bcs file prior to the SCS added code allows the JaheiraHealsB global to be set to 6 and Andarthe to initiate the dialog with the party. I still ran into the issue with blowing Andarthe up without giving him the opportunity to surrender. I would suggest giving him a MINHP1 item (works fine in my game) so he can dialog and surrender, and if the party allows the surrender, provide the same XP by dialog and let him escape, and if the party chooses to kill him anyway, destroy the MINHP1 item by dialog and ApplySpell(Myself,RESTORE_FULL_HEALTH) and summon a few more beasties and shadow druids by script to assist. By the way, BGT has _WOLFDR.cre as the .cre's that are summoned which are non-existant resources in BGT. They would need to be WOLFDR.cre to work.

> WOLFDR.cre repaired v18, confirmed.

> Moving above SCS, requires DavidW to take a look - we can't change order of install or avoid SCS adjusting this with a big script block on our own.

> MINHP, looking...

Added MINHP1 to x#andart.cre via latest DLTCEP.

searching...

ok, DestroyItem("MINHP1") via dialog, so

changes to x#jaqu.d:

* Andart if Beador is Alive, activate */
IF %BGT_VAR%
Global("X#JaheiraHealsB","GLOBAL",5) // was 20 to 23
InMyArea("jaheira")
!StateCheck("jaheira",CD_STATE_NOTVALID)
InMyArea(Player1)
THEN
RESPONSE #100
SetGlobal("X#JaheiraHealsB","GLOBAL",6)
END

/* Andart if Beador is Alive, initiate */
IF %BGT_VAR%
Global("X#JaheiraHealsB","GLOBAL",6)
InMyArea("jaheira")
!StateCheck("jaheira",CD_STATE_NOTVALID)
InMyArea(Player1)
THEN
RESPONSE #100
StartDialogNoSet([PC])
END

/* Andart if Beador is Dead, activate */
IF %BGT_VAR%
Global("X#JQBeadorDead","GLOBAL",2) // was 22 to 24
InMyArea("jaheira")
!StateCheck("jaheira",CD_STATE_NOTVALID)
InMyArea(Player1)
THEN
RESPONSE #100
SetGlobal("X#JQBeadorDead","GLOBAL",3)
END

/* Andarthe if Beador is Dead, initiate */
IF %BGT_VAR%
Global("X#JQBeadorDead","GLOBAL",3)
InMyArea("jaheira")
!StateCheck("jaheira",CD_STATE_NOTVALID)
InMyArea(Player1)
THEN
RESPONSE #100
StartDialogNoSet(Player1)
END

/* Andarthe Attacks */
IF %BGT_VAR%
	Global("X#JaheiraQuestAAttack","GLOBAL",1)
THEN
	RESPONSE #100
		StartCutSceneMode()
		CutSceneId(Player1)
		SetGlobal("X#JaheiraQuestAAttack","GLOBAL",2)
		ActionOverride("jadruid8a",Enemy())
		ActionOverride("takiyah",Enemy())
		JumpToPoint([874.2175])
		FaceObject(Player1)
		CreateCreature("%tutu_var%WOLFDR",[-1.-1],0)
		CreateCreature("%tutu_var%WOLFDR",[-1.-1],0)
		Enemy()
		EndCutSceneMode()
END

/* Combat Scripts and Surrender Script */
IF
  GlobalGT("X#ASL","LOCALS",0)
  HPPercentLT(Myself,50)
THEN
  RESPONSE #100
	SetGlobal("X#ASL","LOCALS",0)
	Spell(Myself,3122)
END

IF
  HasItem("X#ANSPER",Myself)
  HPPercentLT(Myself,50)
THEN
  RESPONSE #100
	DropItem("X#ANSPER",[-1.-1])
END

IF
Global("X#AndSurrender","GLOBAL",0)
HPPercentLT(Myself,50)
THEN
RESPONSE #100
SetGlobal("X#AndSurrender","GLOBAL",1)
ChangeEnemyAlly(Myself,NEUTRAL)
StartDialogNoSet([PC])
END

IF
  HaveSpell(CLERIC_HEAL)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  HPPercentLT(Myself,70)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_HEAL)
END

IF
  StateCheck(Myself,STATE_POISONED)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  HasItem("%tutu_var%POTN20",Myself)
THEN
  RESPONSE #100
	UseItem("%tutu_var%POTN20",Myself)
	SetGlobalTimer("X#ACA","LOCALS",6)
END

IF
  StateCheck(Myself,STATE_POISONED)
  HaveSpell(CLERIC_SLOW_POISON)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !HasItem("%tutu_var%POTN20",Myself)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_SLOW_POISON)
END

IF
  HaveSpell(CLERIC_CURE_SERIOUS_WOUNDS)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  HPPercentLT(Myself,80)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_CURE_SERIOUS_WOUNDS)
END

IF
  HaveSpell(CLERIC_CURE_MEDIUM_WOUNDS)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  HPPercentLT(Myself,85)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_CURE_MEDIUM_WOUNDS)
END

IF
  HaveSpell(CLERIC_CURE_LIGHT_WOUNDS)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  HPPercentLT(Myself,90)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_CURE_LIGHT_WOUNDS)
END

IF
  !Allegiance(Myself,ENEMY)
THEN
  RESPONSE #100
	NoAction()
END

IF
  Detect([GOODCUTOFF])
  HaveSpell(CLERIC_INVISIBILITY_PURGE)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !See(LastSeenBy())
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_INVISIBILITY_PURGE)
END

IF
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !GlobalGT("X#ASF","LOCALS",0)
  HasItem("X#ANSPER",Myself)
THEN
  RESPONSE #100
	UseItem("X#ANSPER",Myself)
	SetGlobal("X#ASF","LOCALS",1)
	SetGlobalTimer("X#ACA","LOCALS",6)
END

IF
  !See([GOODCUTOFF.0.0.FIGHTER_DRUID])
  !See([GOODCUTOFF.0.0.DRUID_ALL])
  !See([GOODCUTOFF.0.0.MAGE_ALL])
  !See([GOODCUTOFF.0.0.CLERIC_ALL])
  !See([GOODCUTOFF.0.0.BARD_ALL])
  !See([GOODCUTOFF])
  False()
THEN
  RESPONSE #100
	Continue()
END

IF
  HaveSpell(CLERIC_DISPEL_MAGIC)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(LastSeenBy(),STATE_SLEEPING)
  !StateCheck(LastSeenBy(),STATE_HELPLESS)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_DISPEL_MAGIC)
END

IF
  HaveSpell(CLERIC_INSECT_PLAGUE)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_INSECT_PLAGUE)
END

IF
  HaveSpell(CLERIC_BARKSKIN)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_BARKSKIN)
END

IF
  HaveSpell(WIZARD_WEB)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(LastSeenBy(),STATE_SLEEPING)
  !StateCheck(LastSeenBy(),STATE_HELPLESS)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREMAGE)
  !HasBounceEffects(LastSeenBy())
  !Range(LastSeenBy(),15)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),WIZARD_WEB)
END

IF
  HaveSpell(CLERIC_RESIST_FIRE)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_RESIST_FIRE)
END

IF
  HaveSpell(CLERIC_MISCAST_MAGIC)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  CheckStatLT(LastSeenBy(),80,SPELLFAILUREMAGE)
  CheckStatLT(LastSeenBy(),80,SPELLFAILUREPRIEST)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_MISCAST_MAGIC)
END

IF
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  HasItem("%tutu_var%POTN21",Myself)
THEN
  RESPONSE #100
	UseItem("%tutu_var%POTN21",Myself)
	SetGlobalTimer("X#ACA","LOCALS",6)
END

IF
  HaveSpell(CLERIC_CONJURE_FIRE_ELEMENTAL)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_CONJURE_FIRE_ELEMENTAL)
END

IF
  HaveSpell(CLERIC_CHARM_PERSON)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(LastSeenBy(),STATE_SLEEPING)
  !StateCheck(LastSeenBy(),STATE_HELPLESS)
  !StateCheck(LastSeenBy(),STATE_CHARMED)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_CHARM_PERSON)
END

IF
  HaveSpell(CLERIC_POISON)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_POISON)
END

IF
  HaveSpell(WIZARD_CHROMATIC_ORB)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(LastSeenBy(),STATE_SLEEPING)
  !StateCheck(LastSeenBy(),STATE_HELPLESS)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREMAGE)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),WIZARD_CHROMATIC_ORB)
END

IF
  HaveSpell(CLERIC_ANIMAL_SUMMONING_1)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_ANIMAL_SUMMONING_1)
END

IF
  HaveSpell(CLERIC_ENTANGLE)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(LastSeenBy(),STATE_SLEEPING)
  !StateCheck(LastSeenBy(),STATE_HELPLESS)
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
  !Range(LastSeenBy(),15)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_ENTANGLE)
END

IF
  HaveSpell(CLERIC_CLOAK_OF_FEAR)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_CLOAK_OF_FEAR)
END

IF
  HaveSpell(CLERIC_SUMMON_INSECTS)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  !HasBounceEffects(LastSeenBy())
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_SUMMON_INSECTS)
END

IF
  HaveSpell(CLERIC_CAUSE_CRITICAL_WOUNDS)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  AttackedBy([0],DEFAULT)
  Range(LastAttackerOf(),6)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),CLERIC_CAUSE_CRITICAL_WOUNDS)
	Attack(LastSeenBy())
END

IF
  HaveSpell(CLERIC_FLAME_BLADE)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
  !StateCheck(Myself,STATE_SILENCED)
  !CheckStatGT(Myself,75,SPELLFAILUREPRIEST)
  AttackedBy([0],DEFAULT)
  Range(LastAttackerOf(),6)
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(Myself,CLERIC_FLAME_BLADE)
	Attack(LastSeenBy())
END

IF
  !GlobalGT("X#ASL","LOCALS",0)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	SetGlobal("X#ASL","LOCALS",1)
	Spell(Myself,4634)
END

IF
  HaveSpell(SALAMANDER_BREATHE_FIREBALL)
  !GlobalTimerNotExpired("X#ACA","LOCALS")
THEN
  RESPONSE #100
	SetGlobalTimer("X#ACA","LOCALS",6)
	Spell(LastSeenBy(),SALAMANDER_BREATHE_FIREBALL)
END

IF
  GlobalTimerNotExpired("X#ACA","LOCALS")
THEN
  RESPONSE #100
	AttackOneRound(LastSeenBy())
END

IF
  !GlobalTimerNotExpired("X#ACA","LOCALS")
THEN
  RESPONSE #100
	Attack(LastSeenBy())
END

IF
  AttackedBy([GOODCUTOFF],DEFAULT)
  !Allegiance(Myself,ENEMY)
THEN
  RESPONSE #100
	Enemy()
END

IF
  AttackedBy([0],DEFAULT)
THEN
  RESPONSE #100
	Attack(LastAttackerOf())
END

[/size]

it looks like this should cover the surrender not happening.
Either way, the quest can continue as long as Jaheira is in the party and ok - any removal of her, and everything stalls.

For docs:

<li> <a href="http://forums.gibberlings3.net/index.php?s=&showtopic=16588&view=findpost&p=152342"> erebusant's "let Andarthe surrender, already!" fix</a> </li>

(oh, and the Amarande/Amaranthe/Andarthe problem -

repairing 3 instances,

Quote

E:\BG1NPC_Workspace\bg1npc-v18_working\bg1npc_18_prerelease\tra\english\x#jaqu.tra (3 hits)
Line 151: @150 = ~Hand over Maretha now, Amaranthe... or are you not truly Archdruid here?~
Line 152: @151 = ~We have freed Maretha now, Amaranthe... she and Beador are beyond your power.~
Line 153: @152 = ~Hear me, Amaranthe! Talk to them, if only for a moment. I'll lead them to destroy the mines. Once Jaheira has seen the wounds the Great Mother had suffered there, she will be more amenable to our cause.~
E:\BG1NPC_Workspace\bg1npc-v18_working\bg1npc_18_prerelease\tra\spanish\x#jaqu.tra (3 hits)
Line 151: @150 = ~Entregad a Maretha ahora, Amaranthe... ¿o en verdad no sois un Archidruida aquí?~
Line 152: @151 = ~Hemos liberado a Maretha, Amaranthe... ella y Beador están más allá de vuestro poder.~
Line 153: @152 = ~¡Oídme, Amaranthe! Hablad con ellos, aunque sólo sea un momento. Les guiaré a destruir las minas. Una vez Jaheira haya visto las heridas que la Gran Madre ha sufrido allí, será más sensible a nuestra causa.~

all standardized to Amarande.

[danemanuelk]

Hello,

I play BWP 8.0.1 Tactics version, with BG1 NPC Project v.17. I have Jaheira (but not Khalid) in my party and I arrive in Clakwood area 1, I found Aldeth the hunter but quest for Jaheira not started. Aldeth have just this dialog line "I don't think that I have anything to say to you". Why? I know in vanilla BG1 Aldeth run and scream for help and after that a dialog appear ... with a shadow druids, but now nothing .... please help

Edited by danemanuelk, 11 September 2009 - 09:18 PM.