13 replies to this topic

[Domi]

You should have an option of gently interrupting the romance with Branwen, telling her to remain friends. It has to be used for the romantic conflict to be resolved. Branwen and Dynaheir also iirc should come to the player, and player will have to pick one at that stage. Both romances should be suspended till then after the drop of the coin.

[Evaine Dian]

Domi, on Oct 8 2008, 05:27 PM, said:

You should have an option of gently interrupting the romance with Branwen, telling her to remain friends. It has to be used for the romantic conflict to be resolved. Branwen and Dynaheir also iirc should come to the player, and player will have to pick one at that stage. Both romances should be suspended till then after the drop of the coin.

I think there is something wrong with the last part of the conflict. I got the banter where they toss the coin ("Dynaheir, I'll go for heads." - DYBRConflict5, x#dyronpc.d), but I never got the last talk where you have to decide who you want to romance ("Branwen, thou dost realize that thy stubbornness brings us back to where we had started?" - DYBRConflict6, same file).



This is DYBRConflict5, the banter where Branwen and Dynaheir toss the coin, found in x#dyronpc.d:

CHAIN IF WEIGHT #-2 ~%BGT_VAR% Global("X#DYBRConflict","GLOBAL",10)~ THEN ~%BRANWEN_BANTER%~ DYBRConflict5
@284
DO ~SetGlobal("X#DYBRConflict","GLOBAL",11) RealSetGlobalTimer("X#DYBRConflictTime","GLOBAL",DYROM_TIMER)~
== ~%DYNAHEIR_BANTER%~ @285
== ~%BRANWEN_BANTER%~ @286
== ~%DYNAHEIR_BANTER%~ @287
== ~%BRANWEN_BANTER%~ @288
== ~%DYNAHEIR_BANTER%~ @289
== ~%BRANWEN_BANTER%~ @290
== ~%DYNAHEIR_BANTER%~ @291
= @292
== ~%BRANWEN_BANTER%~ @293
DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1)
SetGlobal("P#BranwenRomanceActive","GLOBAL",3)~
EXIT

Ok, so at the end of this banter, both romances are suspended; X#DynaheirRomanceInactive=1, P#BranwenRomanceActive=3.



This is DYBRConflict6, the last banter of the conflict, which I never got, same file:

CHAIN IF WEIGHT #-2 ~%BGT_VAR% Global("X#DYBRConflict","GLOBAL",12)~ THEN ~%DYNAHEIR_BANTER%~ DYBRConflict6
@294
DO ~SetGlobal("X#DYBRConflict","GLOBAL",13)~
== ~%BRANWEN_BANTER%~ @295
== ~%DYNAHEIR_BANTER%~ @296
== ~%BRANWEN_BANTER%~ @297
== ~%DYNAHEIR_BANTER%~ @298
END
++ @299 DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1) SetGlobal("P#BranwenRomanceActive","GLOBAL",3)~ EXIT
++ @300 DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1) SetGlobal("P#BranwenRomanceActive","GLOBAL",1)~ EXIT
++ @301 DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",0) SetGlobal("P#BranwenRomanceActive","GLOBAL",3)~ EXIT

This banter fires if X#DYBRConflict=12.



I checked out p#dyrom.baf, and it says the following:

IF %BGT_VAR%
RealGlobalTimerExpired("X#DYBRConflictTime","GLOBAL")
!Global("X#DynaheirRomanceInactive","GLOBAL",1)
Global("X#DynaheirRomanceActive","GLOBAL",1)
!Global("P#BranwenRomanceActive","GLOBAL",3)
Global("P#BranwenRomanceActive","GLOBAL",1)
OR(6)
Global("X#DYBRConflict","GLOBAL",1)
Global("X#DYBRConflict","GLOBAL",3)
Global("X#DYBRConflict","GLOBAL",5)
Global("X#DYBRConflict","GLOBAL",7)
Global("X#DYBRConflict","GLOBAL",9)
Global("X#DYBRConflict","GLOBAL",11)
InParty(Myself)
InParty("branwen")
THEN
RESPONSE #100
IncrementGlobal("X#DYBRConflict","GLOBAL",1)
END

If I am not mistaken, X#DYBRConflict doesn't get set to 12 here, because DYBRConflict5 previously set X#DynaheirRomanceInactive=1 and P#BranwenRomanceActive=3. As a consequence, you don't get to see the very last banter, DYBRConflict6, and both romances are shut down permanently...

[cmorgan]

Hmmm... odd!

Thank you for the code references, I will take a look -

if nothing in related .bcs files (especially Branwen's files, as they interrelate) resets the !Global("X#DynaheirRomanceInactive","GLOBAL",1), I think you are right. There is one more conflict in the file hat was not enabled. (In fact, from my playing and Domi's notes above, I thought the coin toss talk *was* the last one!)


++ @299 DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1) SetGlobal("P#BranwenRomanceActive","GLOBAL",3)~ EXIT

should be choosing neither - it shuts down both romances

++ @300 DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",1) SetGlobal("P#BranwenRomanceActive","GLOBAL",1)~ EXIT

lets Branwen continue at the uncommitted stage, but suspends Dynaheir's

++ @301 DO ~SetGlobal("X#DynaheirRomanceInactive","GLOBAL",0) SetGlobal("P#BranwenRomanceActive","GLOBAL",3)~ EXIT

this one should choose or resume Dynaheir, but stop Branwen.

That looks like the code for completion of the choice - which would mean that DYBRConflict5 is the last in the sequence.

I will take a look at Branwen's and Dynaheir's materials and check on how they work together, and see what we can do. Currently, Option 3 should allow Dy's romance to continue and shut down Branwen's romance. Option 2 should allow Branwen to continue and shut down Dy's.

[Evaine Dian]

cmorgan, on Jun 6 2009, 04:27 PM, said:

That looks like the code for completion of the choice - which would mean that DYBRConflict5 is the last in the sequence.

I will take a look at Branwen's and Dynaheir's materials and check on how they work together, and see what we can do. Currently, Option 3 should allow Dy's romance to continue and shut down Branwen's romance. Option 2 should allow Branwen to continue and shut down Dy's.

Hm, I read your post several times and I'm still not sure if it's just a typo or a misunderstanding. DYBRConflict6 should be the last one.

Domi, on Oct 8 2008, 05:27 PM, said:

Branwen and Dynaheir also iirc should come to the player, and player will have to pick one at that stage. Both romances should be suspended till then after the drop of the coin.

I got the idea that the coin tossing couldn't be the final talk because of Domi's post, not despite of it.

I played as a female PC last week and saw the challenge between Coran and Ajantis. I could choose between them, thus it struck me as odd that Branwen and Dynaheir decided on their own that they didn't want me, and I couldn't do anything about it!

I set X#DYBRConflict=12 via console, got the final banter of the conflict and chose Dynaheir.

[cmorgan]

I understand - I was repeating back to you to make sure I understood I guess to be clear it should have read:

"which would mean that DYBRConflict5 is the last conflict state seen by players in-game, leaving DYBRConflict6 unseen. DYBRConflict5 acts as a default end-of-sequence becasue the way it is coded, the players do make a hidden choice; option 1 shuts them both down, 2 lets Branwen continue, and 3 lets Dy continue. None of this matches Domi's description of what she intended, which is

DYBRConflict5 = suspend both romances

DYBRConflict6 = player chooses between romances"

[Evaine Dian]

The more you repeat back to me, the more you confuse me.

You're right, DYBRConflict5 is the last one you see as a player in-game. But the player doesn't make any choices, not even hidden ones - DYBRConflict5 is just a banter between Dynaheir and Branwen and shuts both romances down, there's nothing you can do about it as a player.

Then, there's DYBRConflict6 which you don't see in-game, and that is the one that has those three choices you mentioned. They aren't hidden, either, but normal reply options.

Clear as mud?

[cmorgan]

I think I understand

[Evaine Dian]

I found some other oddities, all Branwen and/or Dynaheir related, so I'll just post them here.


1) I romanced Dynaheir, Branwen's romance was shut down after the conflict, but I still got a couple of Branwen's LTs - the one at Candlekeep, the one where you are poisoned, the one where she prays for you and the one in the Undercity . It seems that this is not a bug, but by design; it seems that the only requirement is P#BranMatch=1. It's certainly nice that Branwen isn't completely quiet after I ditched her for Dynaheir, but it's weird to see LTs pop up which have reply options like "Branwen, it is natural that we worry about each other. We are in love."... Of course, you don't have to choose the "romantic replies" if you don't want to, but I find it weird that you can in the first place.


2) There is an easter egg involving Dynaheir, Edwin and the Blushing Mermaid, and it seems that it causes a very annoying bug.

Spoiler for everyone who hasn't seen the easter egg:

















When you go to the Blushing Mermaid (ground level), Edwin asks you if you want to have some fun in the Undercellars. If you say yes, Edwin and the PC are teleported to the Undercellars and you get to see a scene with some courtesans. I then declined his offer, because I didn't want to upset Dynaheir, and Edwin and the PC were teleported back to the Blushing Mermaid (ground level).

Up until here, everything was fine. But later, I wanted to enter the Undercellars to get the invitation for Sarevok's coronation, and this is where I encountered a bug. The party entered the Undercellars, the game was autosaved, the guard at the entrance wanted to collect the entry fee, and suddenly, Edwin and the PC get teleported to the ground level of the Blushing Mermaid. They can't really move, because they get teleported to the same spot again and again... The rest of the party is stuck in the Undercellars, and can't get out because I can't gather my party before venturing forth. The only thing I could do to solve the situation was to assign the invitation to my inventory via Shadow Keeper and not enter the Undercellars at all.

I just reloaded the save I had before Edwin asked me to go and see the courtesans. All other outcomes of the scene work just fine - I declined his offer right away; I agreed and chose a courtesan. Both times, I could enter the Undercellars afterwards without any problems, so I guess it is this one option only that is buggy.

The whole sequence is in x#dyronpc.d, at the very end of the file, starting with

IF WEIGHT #-2 ~%BGT_VAR% Global("X#EdwinBlushing","GLOBAL",2)~ THEN BEGIN EdwinConcubines
SAY @331
++ @332 DO ~ SetGlobal("X#EdwinBlushing","GLOBAL",3)~ EXIT
++ @333 + DYEDRORE2.1
++ @334 DO ~ SetGlobal("X#EdwinBlushing","GLOBAL",4)~ EXIT
END

The option that gave me troubles is

IF ~~ THEN REPLY @346 DO ~SetGlobal("X#EdwinBlushing","GLOBAL",7)~ EXIT

(@346  = ~I have changed my mind. The girls are all beautiful, but I have someone dear to me, I'd rather be with.~)

(And I would drop the comma after "I have someone dear to me" --> "I have someone dear to me I'd rather be with.")

[cmorgan]

Evaine Dian, on Jun 9 2009, 04:45 AM, said:

I found some other oddities, all Branwen and/or Dynaheir related, so I'll just post them here.

1) I romanced Dynaheir, Branwen's romance was shut down after the conflict, but I still got a couple of Branwen's LTs - the one at Candlekeep, the one where you are poisoned, the one where she prays for you and the one in the Undercity . It seems that this is not a bug, but by design; it seems that the only requirement is P#BranMatch=1. It's certainly nice that Branwen isn't completely quiet after I ditched her for Dynaheir, but it's weird to see LTs pop up which have reply options like "Branwen, it is natural that we worry about each other. We are in love."... Of course, you don't have to choose the "romantic replies" if you don't want to, but I find it weird that you can in the first place.

Rechecking, I see the conditions - and it looks like these really are supposed to pop up even if you have stopped romancing her. The blocks above it are specific - they all use

Global("P#BranwenRomanceActive","GLOBAL",1)

and these are very specifically *just* looking for the match. In fact, it is even commented in the code:
/* Party Poisoned! Just RomanceMatch=1 */

I suspect this is also because it is possible for her to have "broken up" with you earlier in the game, running out to the end of the romance.

I understand your analysis, but I think the rest of the dialog flow allows an "ex-girlfriend" feel that is in keeping with a follower of Tempus (and close to RL, too - some folks hang around and are close friends, but occasionally push the edges - and dudes don't always avoid saying things that are only partially true...)

The one thing I can do is add the global to the one talk in there that specifically refers to being in love:

IF ~~ P#BRLTPO.5
SAY @556
++ @557 + P#BRLTPO.6
++ @558 + P#BRLTPO.7
++ @559 + P#BRLTPO.8
END

@557  = ~Branwen, it is natural that we worry about each other. We are in love.~
@558  = ~It is only temporary, Branwen. When you're cured of the poison, you'll become yourself again, I'm sure.~
@559  = ~You must steel yourself. If I cannot rely on you, how shall we continue?~

So option 1 only fires if they really are in love and as committed as Branwen gets. That seems to follow author intent, but not jar players.

so, changes:

IF ~~ P#BRLTPO.5
SAY @556
+ ~Global("P#BranwenRomanceActive","GLOBAL",1)~ + @557 + P#BRLTPO.6
++ @558 + P#BRLTPO.7
++ @559 + P#BRLTPO.8
END

For docs:

<li> <a href="http://forums.gibberlings3.net/index.php?s=&showtopic=15740&view=findpost&p=152312"> Player Comment on Shared Love when no longer romancing Branwen blocked. </a> </li>

[cmorgan]

Evaine Dian, on Jun 9 2009, 04:45 AM, said:

2) There is an easter egg involving Dynaheir, Edwin and the Blushing Mermaid, and it seems that it causes a very annoying bug.

Spoiler

When you go to the Blushing Mermaid (ground level), Edwin asks you if you want to have some fun in the Undercellars. If you say yes, Edwin and the PC are teleported to the Undercellars and you get to see a scene with some courtesans. I then declined his offer, because I didn't want to upset Dynaheir, and Edwin and the PC were teleported back to the Blushing Mermaid (ground level).


Up until here, everything was fine. But later, I wanted to enter the Undercellars to get the invitation for Sarevok's coronation, and this is where I encountered a bug. The party entered the Undercellars, the game was autosaved, the guard at the entrance wanted to collect the entry fee, and suddenly, Edwin and the PC get teleported to the ground level of the Blushing Mermaid. They can't really move, because they get teleported to the same spot again and again... The rest of the party is stuck in the Undercellars, and can't get out because I can't gather my party before venturing forth. The only thing I could do to solve the situation was to assign the invitation to my inventory via Shadow Keeper and not enter the Undercellars at all.

I just reloaded the save I had before Edwin asked me to go and see the courtesans. All other outcomes of the scene work just fine - I declined his offer right away; I agreed and chose a courtesan. Both times, I could enter the Undercellars afterwards without any problems, so I guess it is this one option only that is buggy.

Got it - the cutscene which triggers leaves the global open, which means every time Edwin drops by the undercellars again, the following runs -

E:\BG1NPC_Workspace\bg1npc-v18_working\bg1npc_18_prerelease\phase3\dyrom\baf\p#ro0112.baf, last block, appended to the area script -

IF %BGT_VAR%
Global("X#EdwinBlushing","GLOBAL",7)
THEN
RESPONSE #100
ClearAllActions()
ActionOverride("X#NELL",EscapeAreaDestroy(20))
ActionOverride("X#BHET",EscapeAreaDestroy(20))
ActionOverride("X#SVEET",EscapeAreaDestroy(20))
ActionOverride("X#MADR",EscapeAreaDestroy(20))
SmallWait(15)
ActionOverride(Player1,LeaveAreaLUA("%NEBaldursGate_BlushingMermaid_L1%","",[734.619],14))
ActionOverride("edwin",LeaveAreaLUA("%NEBaldursGate_BlushingMermaid_L1%","",[734.619],14))
END

Repaired by advancing the global to something higher than the rest of the sequence: confirmed, 8 does not trigger any other content, so this is the final variable #. Incorporating...

IF %BGT_VAR%
Global("X#EdwinBlushing","GLOBAL",7)
THEN
RESPONSE #100
ClearAllActions()
ActionOverride("X#NELL",EscapeAreaDestroy(20))
ActionOverride("X#BHET",EscapeAreaDestroy(20))
ActionOverride("X#SVEET",EscapeAreaDestroy(20))
ActionOverride("X#MADR",EscapeAreaDestroy(20))
SmallWait(15)
SetGlobal("X#EdwinBlushing","GLOBAL",8)
ActionOverride(Player1,LeaveAreaLUA("%NEBaldursGate_BlushingMermaid_L1%","",[734.619],14))
ActionOverride("edwin",LeaveAreaLUA("%NEBaldursGate_BlushingMermaid_L1%","",[734.619],14))
END

For docs:

<li> <a href="http://forums.gibberlings3.net/index.php?s=&showtopic=15740&view=findpost&p=1523152"> Edwin's Dynaheir Romance Cutscene refusal option fixed.</a> </li>